@echo off
echo ========== RedRocket Hydra Installer ==========

if not exist venv goto no_venv

choice /N /M "A virtual environment already exists. Delete it and reinstall? [Y/N] "
if %errorlevel% equ 1 goto rm_venv
if %errorlevel% equ 2 goto venv_ok
exit /b

:rm_venv
rmdir venv /s /q

:no_venv
echo Trying py 3.13...
py -V:3.13 -m venv venv
if %errorlevel% equ 0 goto venv_ok

echo Trying py 3.12...
py -V:3.12 -m venv venv
if %errorlevel% equ 0 goto venv_ok

echo Trying py 3.11...
py -V:3.11 -m venv venv
if %errorlevel% equ 0 goto venv_ok

echo Trying python...
python -c "import sys; sys.exit(0 if sys.version_info[0] == 3 and sys.version_info[1] in (11, 12, 13) else 1)"
if %errorlevel% neq 0 goto no_python

python -m venv venv
if %errorlevel% equ 0 goto venv_ok

:no_python
echo Trying pymanager...
where /Q pymanager
if %errorlevel% equ 0 goto pymanager_ok

echo.
echo ========== Installing pymanager ==========
winget install 9NQ7512CXL7T
if %errorlevel% neq 0 goto error

:pymanager_ok
echo.
echo ========== Installing Python 3.12 ==========
pymanager exec -V:3.12 -m venv venv
if %errorlevel% neq 0 goto error

:venv_ok
echo Activating environment.
call venv\Scripts\activate.bat
if %errorlevel% neq 0 goto venv_error

if not exist requirements.txt goto no_files

echo Some files are downloaded. If the download was incomplete it should be retried.
choice /N /M "Retry download? [Y/N] "
if %errorlevel% equ 1 goto no_files
if %errorlevel% equ 2 goto files_ok
exit /b

:no_files
where /Q hf
if %errorlevel% equ 0 goto hub_ok

echo.
echo ========== Installing Hugging Face Hub ==========
pip install huggingface_hub
if %errorlevel% neq 0 goto venv_error

:hub_ok
echo.
echo ========== Downloading RedRocket/Hydra ==========
hf download --local-dir=. --exclude "install.bat" --exclude "*jtp-3-hydra*" --exclude "*.jpg" RedRocket/Hydra
if %errorlevel% neq 0 goto error
if not exist requirements.txt goto error

:files_ok
echo.
echo ========== Installing Requirements ==========
pip install -r requirements.txt --extra-index-url https://download.pytorch.org/whl/cu126
if %errorlevel% neq 0 goto venv_error

echo.
echo =============================================
echo =          Installation Successful          =
echo =============================================
echo.
pause
exit /b

:venv_error
rmdir venv /s /q

:error
echo.
echo =============================================
echo =            Installation Failed            =
echo =============================================
echo.
pause
exit